[FMX] 痛苦的先驱 – Android 下部分按键不会触发 KeyDown 事件的处理

做先驱是痛苦的，死的壮烈，活的憋屈。遇到问题，在谷哥和度娘都帮不上忙的情况下，只好自己摸索。相信在黑暗中，总有那么一道光闪过智慧的脑袋瓜子~~~~

前情提要：因为试图要在窗体的 OnKeyDown 事件中响应红外遥控器上的 OK 确认键，结果却痛苦的发现，相应的事件不会被触发，于是痛苦的摸索过程开始了……

（此处省略5000字）

好了，现在告诉大家结果，俺搞定了！

首先说问题的根源在于 FMX.Platform.Android.pas 中，它的 HandleAndroidKeyEvent 是处理键盘事件的，在其中有这么一行：

if not Assigned(SkipEvent) or (SkipEvent.getAction <> Action) or (SkipEvent.getFlags <> AKeyEvent_getFlags(AEvent)) or
    (SkipEvent.getKeyCode <> KeyCode) or (SkipEvent.getMetaState <> MetaState) or (SkipEvent.getEventTime <> EventTime) or
    (SkipEvent.getDownTime <> DownTime) then
  begin
    KeyChar := #0;

    vkKeyCode := PlatformKeyToVirtualKey(KeyCode, KeyKind);

vkKeyCode 需要调用函数 PlatformKeyToVirtualKey 来获取转换后的虚拟键值，而我们看 PlatformKeyToVirtualKey 的实现：

function PlatformKeyToVirtualKey(const PlatformKey: Word; var KeyKind: TKeyKind): Word;
var
  KeyInfo: TVirtualKeyInfo;
begin
  Result := 0;
  KeyKind := TKeyKind.Unknown;
  if Assigned(vKeyMapping) and vKeyMapping.ContainsKey(PlatformKey) then
  begin
    KeyInfo := vKeyMapping[PlatformKey];
    Result := KeyInfo.VirtualKey;
    KeyKind := KeyInfo.KeyKind;
  end;
end;

如果我们跟踪源码，会发现按下 OK 键时 PlatformKey 为 23，而由于在 vKeyMapping 中找不到，所以就返回了 0。而后面的：

if Assigned(FKeyCharacterMap) then
      begin
        KeyChar := Char(ObtainKeyCharacterMap(DeviceId).get(KeyCode, MetaState));
        if KeyChar <> #0 then
          KeyCode := 0
        else
          KeyCode := vkKeyCode;
      end;

里，KeyChar 得到的结果也是0，所以 KeyCode 被赋值为 vkKeyCode。通过前面我们知道 vkKeyCode 的值是0，所以 KeyCode 就是0了。进一步跟踪：

case AKeyEvent_getAction(AEvent) of
      AKEY_EVENT_ACTION_DOWN:
        begin
          if (KeyCode = vkHardwareBack) and (KeyChar = #0) and (VirtualKeyboardAndroid <> nil) and
            (VirtualKeyboardAndroid.VirtualKeyboardState * [TVirtualKeyboardState.Visible] <> []) then
          begin
            FDownKey := 0;
            FDownKeyChar := #0;
          end
          else
          begin
            FDownKey := KeyCode;
            FDownKeyChar := KeyChar;
            TWindowManager.Current.KeyDown(KeyCode, KeyChar, ShiftStateFromMetaState(MetaState));
          end;

在这里符合 else ，进入 KeyDown 事件，然后进一步跟踪会跟踪到 FMX.Form.pas 里的 TCommonCustomForm.KeyDown ，然后你就会发现它没有被触发，而且由于前面的 KeyCode/KeyChar 均为0，已经失去了触发的意义，程序将无法区分这些功能按键。所以解决问题的办法就在于将 KeyCode 处理下，不让其返回0。我们要做的就是将这个按键加入 vKeyMapping 中，让其返回非0值。查看相关函数，我们会发现有两个函数值得我们关注：

function RegisterKeyMapping(const PlatformKey, VirtualKey: Word; const KeyKind: TKeyKind): Boolean;
function UnregisterKeyMapping(const PlatformKey: Word): Boolean;

这两个函数一个负责注册按键映射，另一个负责注销。所以问题也就简单了，我们只需要注册下 23 （Androidapi.Keycodes 里 AKEYCODE_DPAD_CENTER）的值就解决了：

procedure TForm1.FormCreate(Sender: TObject);
begin
RegisterKeyMapping(23,23,TKeyKind.Functional);
end;

好了，这个东东就这么解决了。OnKeyDown 和 OnKeyUp 得到了正确的结果，在 FMX.UITypes 中虚拟键值 23 对应的是 vkJunja ，剩下的就不需要我多说了，如果需要请托梦吧。

登录